FreeBASIC GMP ライブラリを使ったユーザ定義型の活用例

Dim Shared As Long mpf_digits_precision=50

#Include Once "gmpf-overload.bi"

Declare Function factorial(n As ULong,numberbase As Long=10) As String 
'==================================================================
'test

set_precision(10) '変数を定義する前に、精度を設定する

Dim As gmpf xf, yf, zf '自動初期化
Dim As __mpq_struct q2
Dim As String s
Dim As mp_exp_t xp
Dim As Integer i, j

mpq_init(@q2)
mpq_set_ui(@q2, 1, 3) 'q2 = 1/3
zf=q2 'mpq から mpf に自動型変換
Print "mpq 1/3 から mpf に自動型変換"
Print zf.toString("%45.40f"); "     全体 45 桁、小数部 40 桁で実数出力"
Print zf.toString("%45.40e"); " 全体 45 桁、小数部 40 桁で指数表示"
Print zf.toString ; "                           デフォルト表示"
Print "何かキー入力で継続 "
Sleep

Print
For xf="1" To 10 Step "1"
   yf=gmpf_Sqr(xf)
   Print "Sqr(";xf;") =",yf.toString("f") '浮動小数点形式、すべての桁
Next
Print
Print "=================================================================="
Print "デフォルトの精度を50桁に変更する"
Print
set_precision(50) 'デフォルトの精度を変更する
xf.set_prec '定義済みの変数の精度も変更する必要があります
yf.set_prec
zf.set_prec
For xf="1" To 10 Step "1"
   yf=gmpf_Sqr(xf)
   Print "Sqr(";xf;") =",yf.toString("%45.40f") '浮動小数点形式、digits.decimals
Next
Print "何かキー入力で継続 "
Sleep

Print
Print "mpq 1/3 から mpf に自動型変換"
zf=q2
Print zf.toString("%45.40f"); "                       全体 45 桁、小数部 40 桁で実数出力"
Print zf; "      自由形式で表示" '浮動小数点形式、すべての桁
Print zf.toString("e"); "  指数(sci 形式)で表示" 'Scientific notation 形式(電卓では sci モードと表示)、すべての桁
Print
Print "何かキー入力で継続 "
Print
Print "精度を 2,880桁に設定し直して"
Print "最初の 116 フィボナッチ数を計算する"
Sleep

set_precision(2880) '精度を2880桁に設定
xf.set_prec         '変数は事前に50桁の精度で初期化されていたため、
                    'より高い精度で再初期化する必要があります。

s=String(23,"9")+"8"+String(24,"9")
xf=s
xf=1/xf
s=xf.toString("%2885.2880f")
s=Mid(s,4)
'mpf_get_str (s, @xp, 10, 2880, @xf.num)
j=1
For i=1 To 58
   Print Mid(s,j,24),Mid(s,j+24,24)
   If i=50 Then
      Print i*2
   EndIf
   j+=48
Next

mpq_clear(@q2)
'mpf 変数を自動クリーンアップ

Print
Print "階乗を計算"
Print "何かキー入力で継続 "
Sleep

'void mpz_fac_ui (mpz_t rop, unsigned long int op) 
'rop = op!.（階乗）

Print
Dim As mpz_t k
mpz_init(@k)
Dim As Double t=Timer
mpz_fac_ui(@k, 100000)
t=Timer-t
Print "階乗 100000! の計算時間 ";t

Print 
Print "以下は 5000!"
Print "何かキー入力で継続 "
Sleep
Print factorial(5000)
Print

Print "何かキー入力で終了 ";

Sleep

'by dodicat ≫ May 04, 2017 12:37 
'階乗を計算するユーザ定義関数

Function factorial(n As ULong,numberbase As Long=10) As String 
    Dim As __mpz_struct Intanswer
    mpz_init( @Intanswer)
    mpz_fac_ui(@Intanswer,n)
    Dim As ZString Ptr s = mpz_get_str(0, numberbase, @intanswer)
    mpz_clear(@Intanswer)
    Function= Trim(*s)
    DeAllocate(s)
End Function

'Print factorial(150,16) '16 進数で表示
'Print factorial(150,10) '10 進数で表示