FreeBASIC FunctionPtr

Function ConcatSelf( x As String ) As String
    Return x & x
End Function

Dim x As Function( x As String ) As String = ProcPtr( ConcatSelf )

Print x( "Hello" )

Function x2 (ByVal i As Integer) As Integer
  Return i * 2
End Function

Function x3 (ByVal i As Integer) As Integer
  Return i * 3
End Function

Function operation (ByVal i As Integer, ByVal op As Function (ByVal As Integer) As Integer) As Integer
  Return op(i)
End Function

Print operation(4, @x2)
Print operation(4, @x3)

' キー押下イベントを実装するための、基本的なコールバック関数メカニズムの例:
' ( イベント・スレッドの実行中は、ユーザー・コールバック関数のアドレスを変更できません)
'   - 非同期スレッドはループ内でキーボードをテストし、キーが押されるたびに、ユーザー・コールバック関数を呼び出します。
'   - コールバック関数のアドレスが、スレッドに渡されます。
'   - コールバック関数は、押されたキーの文字を出力しますが、
'       押されたキーが <escape> の場合は、関数の戻り値を使ってスレッドに終了を指示します。
'   - ユーザーコールバックアドレスは、引数としてスレッドに渡されるため、スレッドの実行中に変更することはできません。

'' スレッドSub定義
  Sub threadInkey (ByVal p As Any Ptr)
    If p > 0 Then                                                '' テスト条件コールバック関数定義
      Dim As Function (ByRef As String) As Integer callback = p  '' any ptr をコールバック関数ポインタに変換する
      Do
        Dim As String s = Inkey
        If s <> "" Then                                          '' test condition key pressed
          If callback(s) Then                                    '' test condition to finish thread
            Exit Do
          End If
        End If
        Sleep 50, 1
      Loop
    End If
  End Sub

'' user callback Function definition
  Function printInkey (ByRef s As String) As Integer
    If Asc(s) = 27 Then                                        '' test condition key pressed = <escape>
      Print
      Return -1                                                '' order thread to finish
    Else
      Print s;
      Return 0                                                 '' order thread to continue
    End If
  End Function

'' user main code
  Dim As Any Ptr p = ThreadCreate(@threadInkey, @printInkey)   '' コールバック関数のアドレスを渡して、スレッドを起動します。
  ThreadWait(p)                                                '' スレッドの終了を待つ