FreeBASIC SubPtr

    Sub Hello()
        Print "Hello"
    End Sub

    Sub Goodbye()
        Print "Goodbye"
    End Sub

    Dim x As Sub() = ProcPtr( Hello )

    x()

    x = @Goodbye  '' or procptr(Goodbye)

    x()

Sub s0 ()
  Print "'s0 ()'"
End Sub

Sub s1 (ByVal I As Integer)
  Print "'s1 (Byval As Integer)'", I
End Sub

Sub s2 (ByRef S As String, ByVal D As Double)
  Print "'s2 (Byref As String, Byval As Double)'", S, D
End Sub

Dim s0_ptr As Sub () = @s0
Dim s1_ptr As Sub (ByVal I As Integer) = @s1
Dim s2_ptr As Sub (ByRef S As String, ByVal D As Double) = @s2

s0_ptr()
s1_ptr(3)
s2_ptr("PI", 3.14)

' キー押下イベントを実装するための、高度なコールバック Sub メカニズムの例：
' （ユーザー・コールバックの Sub アドレスは、イベント・スレッドの実行中に変更することができます）
'   - 非同期スレッドはループ内でキーボードをテストし、キーが押されるたびにユーザーコールバック Sub を呼び出します。
'   - UDT は、使用される（コールバック Sub ポインタ、押されたキーの文字、スレッド終了フラグ）一般的な変数、
'       および静的スレッド Sub とスレッドハンドルを、グループ化します。
'   - UDT インスタンス・ポインタがスレッドに渡され、スレッドは毎回それをコールバック Sub に送信します。
'   - コールバック Sub は、押されたキーの文字を表示しますが、
'       押されたキーが <escape> の場合、スレッドに終了を指示します。
'   - ユーザー・コールバック・ポインタは UDT のメンバフィールドであるため、スレッドの実行中に変更することができます。


'' UDT for thread environment
  Type threadUDT
    Dim As Sub (ByVal As ThreadUDT Ptr) callback             '' callback Sub pointer
    Dim As Integer threadEnd                                 '' thread end flag
    Dim As String s                                          '' character of the key pressed
    Declare Static Sub threadInkey (ByVal p As Any Ptr)      '' static thread Sub
    Dim As Any Ptr threadHandle                              '' handle to the thread
  End Type

'' thread Sub definition
  Sub threadUDT.threadInkey (ByVal p As Any Ptr)
    Dim As threadUDT Ptr pt = p                              '' convert the any ptr to a threadUDT pointer
    Do
      pt->s = Inkey
      If pt->s <> "" Andalso pt->callback > 0 Then           '' test condition key pressed & callback Sub defined
        pt->callback(p)
      End If
      Sleep 50, 1
    Loop Until pt->threadEnd                                 '' test condition to finish thread
  End Sub

'' user callback Sub definition
  Sub printInkey (ByVal pt As threadUDT Ptr)
    If Asc(pt->s) = 27 Then                                  '' test condition key pressed = <escape>
      pt->threadEnd = -1                                     '' order thread to finish
      Print
    Else
      Print pt->s;
    End If
  End Sub

'' user main code
  Dim As ThreadUDT t                                         '' create an instance of threadUDT
  t.threadHandle = ThreadCreate(@threadUDT.threadInkey, @t)  '' launch the thread, passing the instance address
  t.callback = @printInkey                                   '' initialize the callback Sub pointer
  ThreadWait(t.threadHandle)                                 '' wait for the thread finish