FreeBASIC マニュアルのトップに戻る

FreeBASIC Width

目次→実行時ライブラリー参考→実行画面関連WIDTH←オリジナル・サイト

WIDTH 左にメニュー・フレームが表示されていない場合は、ここをクリックして下さい

←リンク元に戻る プログラム開発関連に戻る

画面表示の、行と桁の数を、設定したり、取得したりします。

構文:
Width [columns] [, rows]
Width Lprint columns
Width {#filenum | devicename }, columns
result = Width ( )

パラメタ:
columns
出力の桁(文字の)
rows
出力の行(文字の)
filenum
適用するファイル番号
devicename
適用する装置名

戻り値:
32 ビットのロングを返します。 現在の設定について、列の数を high word で、コラムの数を low word で示します。

記述:
出力装置(実行画面、プリンタ、テキストファイル)の、文字の最大桁数を設定します。
装置に送られた文字数が、指定幅に到達すると、自動で改行が発生します。

関数として Width を使と、現在の実行画面幅をlow word で、現在の高さをhigh word で、返します。

装置を指定しないと、Width は、アクティブな実行画面/描画画面で実施されます。そして、最大行数を指定する 2つ目の引数が使えます。

描画モードで、Width は、有効な文字の 高さ * 幅 を設定することによって、間接的に字体サイズを選択するために使われます(Screen (描画)を参考ください)。
rows / cols が無効の組み合わせなら、表示画面は、変わりません。

有効な字体の高さは、8画素、14画素、16画素です。 字体は、すべて、8画素の固定幅があります。
(2 番目の例を参照)

描画モードで Width 命令を使うと、画面は強制的に消去 (Cls) されます。
追記:実行画面では、Width コマンドを使っても、画面の表示内容は消去されません。

例:

''実行画面を設定します
Dim As Long w

w = Width
Print "桁: " & LoWord (w)
Print "行: " & HiWord (w)
Print
Print "何かキーを押して下さい。高さを30行に広げます。"
Sleep

Width 80, 30 '高さを30行に広げます
Cls '画面の表示内容を消去します
w = Width
Print "桁: " & LoWord (w)
Print "行: " & HiWord (w)
Print
Print "何かキーを押して下さい。横幅を50桁に狭めます。"
Sleep

Width 50, 30 '横幅を50桁に狭めます
Cls '画面の表示内容を消去します
w = Width
Print "桁: " & LoWord (w)
Print "行: " & HiWord (w)
Print
Print "何かキーを押して下さい。終了します。"
Sleep


''描画画面を設定します
Const W = 320, H = 200
ScreenRes W, H

Dim As Long twid
Dim As UInteger tw, th

'' 現在の文字の幅/高さをとって来て、表示します
twid = Width ()
tw = LoWord(twid): th = HiWord (twid)
Print "Default for current screen (8*8)"
Print "Width:   " & tw
Print "Height: " & th
Sleep

Width W\8, H\16 '' 8*16 の字体を使います

twid = Width ()
tw = LoWord(twid): th = HiWord (twid)
Print "Set to 8*16 font"
Print "Width:   " & tw
Print "Height: " & th
Sleep

Width W\8, H\14 '' 8*14 の字体を使います

twid = Width ()
tw = LoWord(twid): th = HiWord (twid)
Print "Set to 8*14 font"
Print "Width:   " & tw
Print "Height: " & th
Sleep

Width W\8, H\8 '' 8*8 の字体を使います

twid = Width ()
tw = LoWord(twid): th = HiWord (twid)
Print "Set to 8*8 font"
Print "Width:   " & tw
Print "Height: " & th
Sleep



プラットホーム間の差:

QBからの違い:

参照:

実行画面関連 に戻る
←リンク元に戻る プログラム開発関連に戻る
ページ歴史:2023-04-18 03:57:51
日本語翻訳:WATANABE Makoto、原文著作者: SysOp

ホームページのトップに戻る

表示-非営利-継承