FreeBASIC FaqPggetputstructure

'' fbgfx.bi は、画像ヘッダーで直接働くために必要な、構造と定数を含みます。
#include "fbgfx.bi"

'' lang fb では、構造と定数は、FB 名前空間に含まれています。
#if __FB_LANG__ = "fb"
Using FB
#endif


'' 画像の情報を示す関数
Sub show_image_info( ByVal img As Any Ptr )
    Dim As PUT_HEADER Ptr header 'PUT_HEADER の代わりに IMAGE を使うこともできます
    Dim As Integer w, h, bpp, pitch

    header = img
    If( header->type = PUT_HEADER_NEW ) Then

        Print "New style header"

        w = header->width
        h = header->height
        bpp = header->bpp
        pitch = header->pitch

    Else

        Print "Old style header"

        w = header->old.width
        h = header->old.height
        bpp = header->old.bpp
        pitch = w * bpp

    End If

    Print "Image dimensions are " & w & "*" & h
    Print "Image uses " & bpp & " bytes for each pixel"
    Print "A row of image pixels takes " & pitch & " bytes"

End Sub


Dim As Any Ptr picture

ScreenRes 320, 200, 32

picture = ImageCreate( 10, 10, RGB(128, 192, 255) )

Put( 40, 40 ), picture, PSet

show_image_info( picture )

ImageDestroy picture

Sleep

show_image_info( VarPtr( myarray( L ) ) )