FreeBASIC CondSignal

' このとても簡単なコード例は、いくつかの条件変数ルーチンの使い方を示します。
' メインルーチンは、文字列を初期化し、一つのスレッドを作ります。
' メイン・ルーチンは、スレッドから状態信号を受け取るまで、待ちます。そして、補完した文字列を表示します。
' スレッドは文字列を補完して、そして状態信号を送ります。
'
'相互排除の原理 + 単純な同期
'          Thread#A             XOR + ==>            Thread#B
'.....                                     .....
'MutexLock(mut)                            MutexLock(mut)
'  Do_something_with_exclusion               Do_something_with_exclusion
'  Thread_signal = true -------------------> While Thread_signal <> true
'  CondSignal(cond) -------------------------> CondWait(cond, mut)
'  Do_something_with_exclusion      .------> Wend
'MutexUnlock(mut) ------------------'        Thread_signal = false
'.....                                       Do_something_with_exclusion
'.....                                     MutexUnlock(mut)
'.....                                     .....


Dim Shared As Any Ptr mutex
Dim Shared As Any Ptr cond
Dim Shared As String txt
Dim As Any Ptr pt
Dim Shared As Integer ok = 0

Sub thread (ByVal p As Any Ptr)
    Print "スレッドは、文字列を補完しています"
    MutexLock(mutex)
    Sleep 400, 1
    txt &= " スレッドによって補完"
    ok = 1
    CondSignal(cond)
    MutexUnlock(mutex)
    Print "スレッドが、完了した処理を通知します"
End Sub

mutex = MutexCreate
cond = CondCreate

txt = "文字列の例"
Print "main() 文字列を初期化 = " & txt
Print "main は、1つのスレッドをつくります"
Print
pt = ThreadCreate(@thread)
MutexLock(mutex)
While ok <> 1
    CondWait(cond, mutex)
Wend
Print
Print "main() に戻って, 文字列は = " & txt
ok = 0
MutexUnlock(mutex)

ThreadWait(pt)
MutexDestroy(mutex)
CondDestroy(cond)
Sleep